Affichez les références utilisées.

Publié le par Raymond

Pour exécuter correctement votre application, vous avez chargé des librairies ou objets, soit en cochant la référence soit en sélectionnant directement le fichier. Il est parfois difficile de connaître le nom de la librairie car le chemin complet est tronqué dans la fenêtre ou la version de la librairie n'est pas indiquée dans le titre.
Pour afficher tous ces renseignements fort utiles pour votre documentation, il vous suffit d'exécuter une fonction dont le code est indiqué ci-dessous.

Procédez de la manière suivante:

1 - cochez la référence "Microsoft Visual Basic for Application extensibility 5.3"
2 - créez un nouveau module standard et insérez le code suivant par copier/coller:

Option Compare Database
Option Explicit

Public Function GetProjectReferences()
    Dim vbRef As VBIDE.Reference
    Dim strType As String
    Dim strRef As String
    Dim strMsg As String
    For Each vbRef In Application.VBE.ActiveVBProject.References
        With vbRef
            strRef = .Name & " " & .Major & "." & .Minor & vbCrLf
            If (Not .IsBroken) And .Description <> "" Then
                strRef = strRef & vbTab & .Description & vbCrLf
            End If
            If .Type = vbext_rk_Project Then
                strType = "Projet"
            Else
                strType = "Librairie"
            End If
            If .BuiltIn Then
                strType = strType & "/Interne"
            Else
                strType = strType & "/Externe"
            End If
            If .IsBroken Then
                strType = strType & " - Référence corrompue!"
            Else
                strType = strType & " - Référence correcte."
            End If
            strRef = strRef & vbTab & strType & vbCrLf
            strRef = strRef & vbTab & .FullPath & vbCrLf
        End With
        strMsg = strMsg & strRef
    Next
    Debug.Print "References du projet " & Application.VBE.ActiveVBProject.Name
    Debug.Print strMsg
End Function

3 - Enregistrez votre projet

4 - Affichez la fenêtre exécution

5 - Cliquez à l'intérieur de la fonction GetProjectReferences

6 - Enfoncez la touche F5

7 - Toutes les caractéristiques des références cochées de votre projet sont affichées dans la fenêtre exécution.

8 - Faîtes un copier/coller de la fenêtre exécution dans Word et Imprimez.

9 - Supprimez éventuellement le module standard qui n'est plus utile à votre application.

Exemple de Résultat affiché en fenêtre exécution:

References du projet Favoris
VBA 4.0
    Visual Basic For Applications
    Librairie/Interne - Référence correcte.
    C:/Program Files/Fichiers communs/Microsoft Shared/VBA/VBA6/VBE6.DLL
Access 9.0
    Microsoft Access 12.0 Object Library
    Librairie/Interne - Référence correcte.
    C:/Program Files/Microsoft Office/Office12/MSACC.OLB
stdole 2.0
    OLE Automation
    Librairie/Externe - Référence correcte.
    C:/WINDOWS/system32/stdole2.tlb
DAO 12.0
    Microsoft Office 12.0 Access database engine Object Library
    Librairie/Externe - Référence correcte.
    C:/PROGRA~1/FICHIE~1/MICROS~1/OFFICE12/ACEDAO.DLL
Office 2.4
    Microsoft Office 12.0 Object Library
    Librairie/Externe - Référence correcte.
    C:/Program Files/Fichiers communs/Microsoft Shared/OFFICE12/MSO.DLL
AccessDE 1.0
    Access Developer Extensions Type Library
    Librairie/Externe - Référence correcte.
    C:/PROGRA~1/MICROS~2/Office12/ADDINS/AccessDE.DLL
VBIDE 5.3
    Microsoft Visual Basic for Applications Extensibility 5.3
    Librairie/Externe - Référence correcte.
    C:/Program Files/Fichiers communs/Microsoft Shared/VBA/VBA6/VBE6EXT.OLB

Publié dans Astuces

Commenter cet article